import Tuple.*;
 
//created=24 Oct 07
//description=Selecting triangles in a 3D mesh
//title=Picking
//publish=true
 
import SGGUI.*;
import SGCamera.*;
import Raytracing.*;
 
SGCamera cam; 
Raytracer tracer;
 
KDTree accel;
 
SGGUI controller;
VerticalLayout settings;
 
SGSlider fov;
SGCheckBox showOctree;
 
PFont fnt;  
 
Triangle picked;
    
void setup(){
 
  size(550,550,P3D);
  frameRate(30);
  fnt = loadFont("writing.vlw");
  textFont(fnt);
  textMode(SCREEN);
  
  controller = new SGGUI(this,fnt);
  controller.GUI_HIGHLIGHT = color(200,220,200);
  settings = new VerticalLayout(controller,10,10,150);
  settings.title = "Settings";
  fov = new SGSlider( "Cam FOV",1.5,.1,1,2.5);
  showOctree = new SGCheckBox("Show KD-Tree",0);
 
 
  settings.add(showOctree);
  settings.add(fov);
  controller.add(settings);
 
 
         
  cam = new SGCamera(this,100,-50,100,0,0,0,SGCamera.ORBIT,SGCamera.DOLLY);
 
  tracer = new Raytracer(this);
  tracer.openFile("phex.mra",cam);
 
  accel = (KDTree)tracer.accelerator;
 
  cam.lookAt(0,0,0);
 
}
 
public void draw(){
 
  background(255);
  cam.feed();
  cam.fov = fov.getVal();
  
  //see if the checkbox is hit
  accel.showTree = showOctree.getVal(); 
  tracer.draw();
 
  //highlight the selected triangle
  if (picked != null){
    stroke(0,0,0,100);
    fill(255,255,255,150);
    beginShape();
            vertex(picked.vert0.x,picked.vert0.y,picked.vert0.z);
            vertex(picked.vert1.x,picked.vert1.y,picked.vert1.z);
            vertex(picked.vert2.x,picked.vert2.y,picked.vert2.z);
    endShape();
 
  }
 
}
 
void mouseMoved(){
  
  //get the direction vector from the origin through the
  //screen point that the user clicked on 
  Tuple3f direction = cam.getRay(mouseX,mouseY);
  
  //prepare the picking ray
  Ray pick = new Ray(cam.pos, direction);
 
  //intersect the camera ray with the scene
  accel.findNearest(pick);
  
  //if ray intersects anything, highlight it
  if (pick.occluder != null){
    picked = (Triangle)pick.occluder;
  }
  else{
    picked = null;
  }  
  
 
}